Exploring Where & Why/Exploring Where & Why.iso/pc/Lib.cst/00003_Global Scripts for Integration.ls

Text File | 2004-07-11 | 11.8 KB | 555 lines

--
-- Global Scripts for Integration
--

-- these are global scripts that abstract the integration from the OOP implementation.
-- this is the full set of scripts that can be used for integration.
-- the score should never directly refer to an object.


global gameObj, gUI  -- the two instantiated objects.
global gType  -- the type of the current activity (if any)
global gOldDepth  -- the original colorDepth of the monitor (to be restored at end of play)
global gSoundList  -- a globally used list of sounds.
global gDebug  -- only active in unprotected movies.

--commonly used buttons
global gPrinterB,gBannerartB,gLeftB,gSpeakerB,gHomeB,gHelpB,gRightB

global gTotalSprites,version

-- start the application for the first time:

on startApplication
  --  if the optionDown then
  --    set memwin = window "memmon"
  --    set the fileName of memwin = the pathname & "memmon"
  --    open memwin
  --  end if
  if the movieName contains ".dir" then set gDebug = TRUE

  set the exitLock to TRUE
  if voidP (gOldDepth) then

    set gOldDepth = the colorDepth
    --JCODE
    --    if the machineType = 256 then
    --      if the colorDepth = 8 then
    --        put the colorDepth
    --      else
    --        alert "For better performance, we recommend that you change the monitor resolution to 256 colors."
    --      end if
    --    else
    --      if the colordepth <> 8 then set the colorDepth = 8
    --    end if
    --END JCODE
  end if

  -- set the timeoutLength = (30 * 60)
  set the timeoutPlay = TRUE

  set gType = 0

  set gPrinterB=114
  set gBannerartB=115
  set gLeftB=116
  set gSpeakerB=117
  set gHomeB=118
  set gHelpB=119
  set gRightB=120

  if not objectP (gUI) then
    set gUI = new (script "Application")
  end if


end


-- should be called by startmovie **always**

on startLib
  if not objectP (gUI) then set gUI = new (script "Application")

  if objectP (gameObj) then destruct (gameObj)
  set gameObj = 0
  set gType = 0

  clearBanner()

  unloadCast (gUI)
  cursor -1

  if objectP (gUI) then set UI = gUI
  set oldDepth = gOldDepth
  set soundList = gSoundList
  set debug = gDebug

  clearglobals

  set gUI = UI
  set gOldDepth = oldDepth
  set gSoundList = soundList
  set gDebug = debug

  checkGUICursors (gUI)

  --added by alex m.
  --set sprite numbers for commonly used buttons (Director 6.0 only)
  set gPrinterB=114
  set gBannerartB=115
  set gLeftB=116
  set gSpeakerB=117
  set gHomeB=118
  set gHelpB=119
  set gRightB=120

  if char 1 of version="6" then
    set gTotalSprites=120 --director 6.0
  else if char 1 of version="5" then
    set gTotalSprites=48  --5.0
  else
    --JCODE
    set gTotalSprites=120
    --END JCODE
  end if
end


-- should be called by stopmovie **always**

on stopLib
  put "stopping..."
  if isSelfContained (gUI) then closeAll ()  -- destruct both objects.
  else if objectP (gameObj) then
    destruct (gameObj)
    set gameObj = 0
  end if
  --saveMovie
  cursor 4
end


-- close the navigation (on quit)

on closeNavigation
  --JCODE
  --if objectP (gUI) then destruct (gUI)
  --set gUI = 0
end


on playPosFeedback
  playResponseSound (1, 1)
end


on playNegFeedback
  playResponseSound (0, 1)
end


-- do a mousedown action.
-- pass the sprite of that action to the activity object
-- if a failure, then pass that action to the navigation object

on doAction spr

  if objectP (gUI) then
    if mouseDown (gUI, spr) then return
  end if

  if objectP (gameObj) then
    if mouseDown (gameObj, spr) then return
  end if

  pass
end


-- initialize the activity.
-- the movie must be on the correct frame when this is called.

on initActivityLib type
  if not objectP (gameObj) then
    cursor 4
    set gType = type
    set gameObj = new (script string (type))
    cursor -1
  end if
end


-- start the activity:

on initializeRound command
  if objectP (gameObj) then
    cursor 4
    -- clearBanner (gUI)  -- EWW2 has intelligible final instructions, don't clear them!
    initializeRound (gameObj)
    if command <> #playControl then go "play"
    unloadCast (gUI)
    cursor -1
  end if
end


-- reinitialize the activity:

on reinitActivity
  if objectP (gameObj) then killActorList (gameObj)
  updateStage
  go "init"
end


-- close all instantiated objects (as with ending play):

on closeAll
  if objectP (gameObj) then destruct (gameObj)
  set gameObj = 0
  if objectP (gUI) then destruct (gUI)
  set gUI = 0
end



-----------------
-- general tools:
-----------------


on killActorList
  killActorList (gUI)
end


-- check and clear memory:

on unloadAll
  unloadCast (gUI)
end


-- do a basic button animation by name
-- return 1 if successful, 0 if not.

on basicNameAnim name, spr
  return basicNameAnim (gUI, name, spr, 6)
end


-- turn all sprites off:

on spritesOff
  spritesOff (gUI)
end


-- manually close help:

on closeHelp
  closeHelpWin (gUI)
end


-- set up the name entry field before displaying the name field on the certificate:

on setUpPrintField
  set nameSpr = 113
  puppetSprite nameSpr, FALSE
  set the text of member the memberNum of sprite nameSpr of castLib the castLibNum of sprite nameSpr to "Your Name"
  set the rect of member the memberNum of sprite nameSpr of castLib the castLibNum of sprite nameSpr to rect (0,0,360,40)
  set the border of member the memberNum of sprite nameSpr of castLib the castLibNum of sprite nameSpr to 0
  set the editable of member the memberNum of sprite nameSpr of castLib the castLibNum of sprite nameSpr to TRUE
  set the hilite of member the memberNum of sprite nameSpr of castLib the castLibNum of sprite nameSpr to TRUE
  set the selStart = 0
  set the selEnd = length (the text of member the memberNum of sprite nameSpr of castLib the castLibNum of sprite nameSpr)
  unloadCast (gUI)
end


-- do a standard button animation
-- return 1 if successful.

on buttonDown spr
  set name = item 1 of the name of member the memberNum of sprite spr of castLib the castLIbNum of sprite spr
  return basicNameAnim (gUI, name, spr, 6)
end


-- print the screen area.
-- customize the area by passing a rect.

on print r, noTextFlag, noFooterFlag
  printActivitySpace (gUI, r, noTextFlag, noFooterFlag)
end


-- clear the input buffer:

on clearEvents
  clearEvents (gUI)
end


-- set up the banner and play it.
-- pass the rootname for the banner.
-- if noPlay = TRUE then don't play the banner after setting it up

on setUpBanner rootName, noPlay
  if objectP (gUI) then setUpBanner (gUI, rootName, noPlay)
  else alert "gUI was not instantiated."
end


on clearBanner
  if objectP (gUI) then clearBanner (gUI)
  else alert "gUI was not instantiated."
end



---------------------------------
-- activity modification scripts:
---------------------------------


-- don't allow a visual change of direction in a DirectionArrow activity:

on showDirectionOff
  if not objectP (gameObj) then
    alert "gameObj was not instantiated."
    return
  end if

  showDirectionOff (gameObj)
end


on clearCanvas
  if not objectP (gameObj) then
    alert "gameObj was not instantiated."
    return
  end if

  clearCanvas(gameObj)
end


-- for #StdPaint only:
-- start the canvas screen with a bitmap
-- if this modification script is used, be sure that the bitmap cast member has a unique name!  There is currently no check for it.
-- also, the bitmap image must be 468 x 345

on initStartingPict bmpMemberName
  if not objectP (gameObj) then
    alert "gameObj was not instantiated."
    return
  end if

  initStartingPict (gameObj, bmpMemberName)
end

-- will force a type for the movie without initializing that type.
-- should be used in non-standard movies that need certain type characteristics (like C&I help pop-up)

on forceActivityType type
  set gType = type
end


-- remove clicked graphics from the screen after they are hit.
-- after this call, clicked objects will disappear from the screen:

on removeClicked
  removeClicked (gameObj)
end


-- add a graph to the activity (to be incremented on a correct hit)
-- makeGraph ([name of basket], [spriteNum to move], [increment in pixels], [direction of movement])
-- directions: #up, #down, #left, #right

on makeGraph name, spr, pixels, direction
  if not objectP (gameObj) then
    alert "gameObj was not instantiated."
    return
  end if

  makeGraph (gameObj, name, spr, pixels, direction)
end


-- turn off the snap to functionality for drag drop and stick activities.
-- after this call, drag & stick games will not snap to postition.

on snapOff
  if not objectP (gameObj) then
    alert "gameObj was not instantiated."
    return
  end if

  snapOff (gameObj)
end


-- turn the randomizing off:

on randomOff
  randomOff (gameObj)
end


-- set the maximum allowable clickables in a round of play:

on setMaxClickables num
  setMaxClickables (gameObj, num)
end


-- set the order of presentation (single point styles) to that of the pool order:

on setByPoolOrder
  setByPoolOrder (gameObj)
end


-- change the hilite ink for drag and drop rollovers.
-- all subsequent rollovers will have the new hilite ink:

on setHiliteInk num
  if not objectP (gameObj) then
    alert "gameObj was not instantiated."
    return
  end if

  setHiliteInk (gameObj, num)
end


-- add a jiggle button to the jiggle button list.
-- if num is an integer, then it will jiggle by sprite number, if it is a command then
-- it will map to a corresponding sprite number.

on addJiggleButton num
  case (num) of
    #print:  set num = gPrinterB
    #next:   set num = gRightB
    #home:   set num = gHomeB
    otherwise nothing
  end case

  add(the actorList, new(script "JiggleSprite Class", num))
end


-- check to see if we are done with a click & identify game:

on checkDone
  if objectP (gameObj) then done (gameObj)
end


-- move straight to the next activity in the series (if the last then return to main menu)
-- do not pass go.

on nextActivity
  if objectP (gUI) then next (gUI)
end


-- initialize a picture link.
-- for C&I and single point games, a picture will be placed in the
-- link sprite each time the user is prompted.  Link pictures should be placed in a cast whose root name
-- is the name of the clickable cast or the draggable cast with "PictureLinks" appended.

on initPictLink spr
  if objectP (gameObj) then initPictLink (gameObj, spr)
end


-- turn off the beep and "good job" reinforcement for this activity.
-- no positive response sound will be played after this is called:

on noResponse
  if objectP (gameObj) then noResponse (gameObj)
end


-- turn off the positive ID sound for click and identify games.
-- (useful for including ID sounds in animation sequences.)

on noIDSound
  if objectP (gameObj) then noIDSound (gameObj)
end


-- in drag drop & stick exercise, do not give pos or neg reinforcement during play.
-- However, give positive reinforcement upon completion.

on waitResponse
  waitResponse (gameObj)
end


------------------
-- for development
------------------

-- debug abstraction:

on debug info
  if the optionDown then put info
end


-- default mouseDown behavior.

on mouseDown
  nothing
end


on timeOut
  if objectP (gameObj) then timeOut (gameObj)
  if objectP (gUI) then timeOut (gUI)
end


on enterFrame
  if objectP (gameObj) then stepFrame (gameObj)
  if objectP (gUI) then stepFrame (gUI)
end


--added by alex m.
--plays several audio files and animates speaker
on animateSpeaker gSpeakerB,audioList
  repeat with audio in audioList
    puppetSound (audio&",prompt"),1
    updatestage
    set i=1
    repeat while soundBusy(1)
      --JCODE
      theMemName = "speaker,"&i
      set theMember = member theMemName of castLib "UI.cst"
      set the member of sprite gSpeakerB = theMember
      --END JCODE
      updateStage
      await 0.2
      set i=i+1
      if i=3 then set i=1
    end repeat
    set the member of sprite gSpeakerB=member "speaker"  of castLib "UI.cst"
    updateStage
  end repeat
end


on await t
  starttimer
  repeat while the timer <60*t
    updatestage
  end repeat
end